USE master	-- (Can't sit in the database whilst its being restored!)
GO

ALTER DATABASE TARGET_DATABASE SET SINGLE_USER WITH ROLLBACK IMMEDIATE
GO

RESTORE DATABASE TARGET_DATABASE
	FROM DISK = 'x:\PathToBackupFile\SOURCE_DATABASE_BACKUPFILE.BAK'
	WITH
		REPLACE,
--		NORECOVERY,	-- Use if more T/Logs to recover
		RECOVERY,	-- Use if no more T/Logs to recover
		STATS = 10,	-- Show progress (every 10%)
	MOVE 'SOURCE_DB_LOGICAL_NAME_data' TO 'x:\SomeRestorePath\TARGET_DATABASE.mdf', 
	MOVE 'SOURCE_DB_LOGICAL_NAME_log' TO 'x:\SomeRestorePath\TARGET_DATABASE.ldf'
GO

/*
-- If restoring additional TRANSACTION LOGs, after the main backup:
-- Make sure the NORECOVERY option is used above
-- then repeat the following for latest differential backup

RESTORE DATABASE TARGET_DATABASE
	FROM DISK = 'x:\PathToBackupFile\TARGET_DATABASE_yyyymmdd_hhmm_Diff.BAK'
	WITH
--		RECOVERY,	-- Use if NO more T/Logs to recover
		NORECOVERY,	-- Use if there are T/Logs to recover
		STATS = 10	-- Show progress (every 10%)

-- then repeat the following for each transaction log, in order
RESTORE LOG TARGET_DATABASE
	FROM DISK = 'x:\PathToBackupFile\TARGET_DATABASE_yyyymmdd_hhmm_Trans.BAK'
	WITH
--		RECOVERY,	-- Use if NO more T/Logs to recover
		NORECOVERY,	-- Use if more T/Logs to recover
		STATS = 10	-- Show progress (every 10%)
*/

-- Rename logical names:
	ALTER DATABASE TARGET_DATABASE 
		MODIFY FILE (NAME = 'SOURCE_DB_LOGICAL_NAME_data', 
				NEWNAME = 'TARGET_DATABASE_data')
GO
	ALTER DATABASE TARGET_DATABASE 
		MODIFY FILE (NAME = 'SOURCE_DB_LOGICAL_NAME_log', 
				NEWNAME = 'TARGET_DATABASE_log')
GO

quote:

---

Originally posted by Kristen

Are you using Enterprise Manger or just raw T-SQL (e.g. in Query Analyser)?

Kristen

---

quote:

---

Originally posted by Luis Martin

Did you check destination path exist?

---